patrick/plasp
Archived
1
0
Fork 0
Code Issues 12 Releases 8 Activity

Added a sequential, fixed-horizon meta encoding.

Browse Source
This commit is contained in:
Patrick Lühne 2016-11-20 23:52:55 +01:00
parent 8bab1e19cb
commit 91b2a23c78
Signed by: patrick
GPG Key ID: 05F3611E97A70ABF
1 changed files with 36 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

36
encodings/sequential-horizon.lp Normal file
View File

@ -0,0 +1,36 @@
#const horizon=1.
% Check feature requirements
:- requires(feature(actionCosts)).
:- requires(feature(axiomRules)).
:- requires(feature(conditionalEffects)).
% Horizon, must be defined externally
time(0..horizon).
% Establish initial state
holds(Variable, Value, 0) :- initialState(Variable, Value).
% Perform actions
1 {occurs(Action, T) : action(Action)} 1 :- time(T), T > 0.
% Check preconditions
:- occurs(Action, T), precondition(Action, Variable, Value), not holds(Variable, Value, T - 1), time(T), time(T - 1).
% Apply effects
caused(Variable, Value, T) :- occurs(Action, T), postcondition(Action, _, Variable, Value).
modified(Variable, T) :- caused(Variable, Value, T).
holds(Variable, Value, T) :- caused(Variable, Value, T), time(T).
holds(Variable, Value, T) :- holds(Variable, Value, T - 1), not modified(Variable, T), time(T), time(T - 1).
% Check that variables have unique values
:- variable(Variable), not 1 {holds(Variable, Value, T) : contains(Variable, Value)} 1, time(T).
% Check mutexes
:- mutexGroup(MutexGroup), not {holds(Variable, Value, T) : contains(MutexGroup, Variable, Value)} 1, time(T).
% Verify that goal is met
:- goal(Variable, Value), not holds(Variable, Value, horizon).
#show occurs/2.